#!groovy

def repository = "registry.c.test-chamber-13.lan"
def repositoryCreds = "harbor-repository-creds"

def workspace
def k8slensVersion
def jsNodeID
def doBuild = false

def label = "kubernetes-${UUID.randomUUID().toString()}"
def templateName = "pipeline-worker"
pipeline {
    agent {
        kubernetes {
            yaml functions.podYaml(
                repo: repository,
                templateName: templateName,
                alpine: true,
                [
                    [
                        name: "ubuntu-focal",
                        path: "${repository}/dockerhub/library/ubuntu:focal",
                        command: "/bin/sh"
                    ]
                ]
            )
        }
    }

    stages {
        stage ('Initalize Jenkins') {
            steps {
                script {
                    workspace = pwd()
                }
            }
        }

        stage ('Get latest Tag') {
            steps {
                container ('alpine') {
                    script {
                        sh """
                            if ! command -v git &> /dev/null; then
                                apk add --no-cache git
                            fi
                            if ! command -v curl &> /dev/null; then
                                apk add --no-cache curl
                            fi
                            if ! command -v jq &> /dev/null; then
                                apk add --no-cache jq
                            fi
                            apk add --no-cache coreutils
                        """
                        k8slensVersion = sh (
                            script: """
                                curl \
                                    --location \
                                    --silent \
                                    --fail \
                                    --request GET \
                                    --url https://api.github.com/repos/lensapp/lens/releases/latest | \
                                    jq --raw 'select(.prerelease == false) | .tag_name[1:]'
                            """,
                            returnStdout: true
                        ).trim()
                    }
                }
                script {
                    if (k8slensVersion ==~ '([5-9]|[0-9]{2,})\\.[0-9]+\\.[0-9]+$') {
                        if (k8slensVersion ==~ '6\\.[0-9]+\\.[0-9]+$') {
                            echo "Version (${k8slensVersion}) is valid, we will build it with node 16."
                            doBuild = true
                            jsNodeID = 'ubuntu-focal'
                        } else {
                            echo "Version (${k8slensVersion}) is not valid, we will not build it."
                        }
                    } else {
                        echo "Version (${k8slensVersion}) is not valid, we will not build it."
                    }
                }
            }
        }

        stage('Pull K8S Lens Source Code') {
            when {
                expression {
                    return doBuild
                }
            }
            steps {
                script {
                    dir("lens") {
                        checkout ([
                            $class: "GitSCM",
                            branches: [
                                [
                                    name: "refs/tags/v" + k8slensVersion,
                                ],
                            ],
                            userRemoteConfigs: [
                                [
                                    url: "https://github.com/lensapp/lens.git",
                                ],
                            ],
                            extensions: [
                                [
                                    $class: "CloneOption",
                                    shallow: true,
                                ],
                                [
                                    $class: "CheckoutOption",
                                    timeout: 2,
                                ],
                            ],
                        ])
                    }
                }
            }
        }

        stage ('Build K8S Lens') {
            when {
                expression {
                    return doBuild
                }
            }
            steps {
                container (jsNodeID) {
                    script {
                        sh """
                            apt update
                            apt install --no-install-recommends -y curl ca-certificates gcc g++ make git rpm
                            curl -fsSL https://deb.nodesource.com/setup_16.x | bash -
                            curl -sL https://dl.yarnpkg.com/debian/pubkey.gpg | gpg --dearmor | tee /usr/share/keyrings/yarnkey.gpg > /dev/null
                            echo "deb [signed-by=/usr/share/keyrings/yarnkey.gpg] https://dl.yarnpkg.com/debian stable main" | tee /etc/apt/sources.list.d/yarn.list
                            apt update
                            apt install yarn nodejs
                            cd "${workspace}/lens"
                            make build
                        """
                    }
                }
            }
        }

        stage ('Push Artifacts') {
            when {
                expression {
                    return doBuild
                }
            }
            steps {
                container('alpine') {
                    script {
                        def appName = sh (
                            script: """
                                printf '%s\\n' "\$(basename "\$(find ./ -name "*.AppImage")")"
                            """,
                            returnStdout: true
                        ).trim()
                        functions.pushArtifact(
                            repoCreds: "nexus-generic-upload-bot",
                            fileName: appName,
                            filePath: workspace + "/lens/dist/",
                            fileURL: "https://nexus.c.test-chamber-13.lan/repository/generic/appimage/"
                        )
                    }
                }
            }
        }
    }
}