Initial checkin of PuTTY installer script and associated files.

[originally from svn r1969]

README.txt

@@ -0,0 +1,34 @@
+PuTTY README
+============
+
+This is the README file for the PuTTY installer distribution. If
+you're reading this, you've probably just run our installer and
+installed PuTTY on your system.
+
+What should I do next?
+----------------------
+
+If you want to use PuTTY to connect to other computers, or use PSFTP
+to transfer files, you should just be able to run them from the
+Start menu.
+
+If you want to use the command-line-only file transfer utility PSCP,
+you will probably want to put the PuTTY installation directory to be
+on your PATH. How you do this depends on your version of Windows. On
+Windows NT and 2000, you can set it using Control Panel > System; on
+Windows 95 you will need to edit AUTOEXEC.BAT. Consult your Windows
+manuals for details.
+
+What do I do if it doesn't work?
+--------------------------------
+
+The PuTTY home web site is
+
+    http://www.chiark.greenend.org.uk/~sgtatham/putty/
+
+Here you will find our list of known bugs and pending feature
+requests. If your problem is not listed in there, or in the FAQ, or
+in the manuals, read the Feedback page to find out how to report
+bugs to us. PLEASE read the Feedback page carefully: it is there to
+save you time as well as us. Do not send us one-line bug reports
+telling us `it doesn't work'.

putty.iss

@@ -0,0 +1,62 @@
+; -*- no -*-
+; putty.iss
+;
+; -- Inno Setup installer script for PuTTY and its related tools.
+;
+; TODO for future releases:
+;
+;  - It would be neighbourly to set up an [UninstallRun] entry that ran
+;    some close cousin of `putty -cleanup', only it should prompt first
+;    in case the user wants to keep stuff. And make the `leave it alone'
+;    button the DEFAULT. And perhaps warn that on NT-style systems not
+;    everything will be caught by this.
+;
+;  - The Quick Launch bar is an interesting thought. Certainly a fair
+;    number of people actually _believe_ my silly joke about how PuTTY
+;    is the only thing that makes Windows usable, so perhaps they'd like
+;    that. Unchecked by default, though, I think.
+;     * does this need to be conditional on the Windows version?
+
+[Setup]
+AppName=PuTTY
+AppVerName=PuTTY prerelease 0.53p
+DefaultDirName={pf}\PuTTY
+DefaultGroupName=PuTTY
+UninstallDisplayIcon={app}\putty.exe
+ChangesAssociations=yes
+Compression=zip/9
+
+[Files]
+Source: "putty.exe"; DestDir: "{app}"
+Source: "pageant.exe"; DestDir: "{app}"
+Source: "puttygen.exe"; DestDir: "{app}"
+Source: "pscp.exe"; DestDir: "{app}"
+Source: "psftp.exe"; DestDir: "{app}"
+Source: "plink.exe"; DestDir: "{app}"
+Source: "website.url"; DestDir: "{app}"
+Source: "doc\putty.hlp"; DestDir: "{app}"
+Source: "doc\putty.cnt"; DestDir: "{app}"
+Source: "LICENCE"; DestDir: "{app}"
+Source: "README.txt"; DestDir: "{app}"; Flags: isreadme
+
+[Icons]
+Name: "{group}\PuTTY"; Filename: "{app}\putty.exe"; Tasks: startmenu
+Name: "{group}\PuTTY Manual"; Filename: "{app}\putty.hlp"; Tasks: startmenu
+Name: "{group}\PuTTY Web Site"; Filename: "{app}\website.url"; Tasks: startmenu
+Name: "{group}\PSFTP"; Filename: "{app}\psftp.exe"; Tasks: startmenu
+Name: "{group}\PuTTYgen"; Filename: "{app}\puttygen.exe"; Tasks: startmenu
+Name: "{group}\Pageant"; Filename: "{app}\pageant.exe"; Tasks: startmenu
+Name: "{userdesktop}\PuTTY"; Filename: "{app}\putty.exe"; Tasks: desktopicon
+
+[Tasks]
+Name: startmenu; Description: "Create a &Start Menu group"
+Name: desktopicon; Description: "Create a &desktop icon for PuTTY"
+Name: associate; Description: "&Associate .PPK files (PuTTY Private Key) with Pageant"
+
+[Registry]
+Root: HKCR; Subkey: ".ppk"; ValueType: string; ValueName: ""; ValueData: "PuTTYPrivateKey"; Flags: uninsdeletevalue; Tasks: associate
+Root: HKCR; Subkey: "PuTTYPrivateKey"; ValueType: string; ValueName: ""; ValueData: "PuTTY Private Key File"; Flags: uninsdeletekey; Tasks: associate
+Root: HKCR; Subkey: "PuTTYPrivateKey\DefaultIcon"; ValueType: string; ValueName: ""; ValueData: "{app}\pageant.exe,0"; Tasks: associate
+Root: HKCR; Subkey: "PuTTYPrivateKey\shell\open\command"; ValueType: string; ValueName: ""; ValueData: """{app}\pageant.exe"" ""%1"""; Tasks: associate
+Root: HKCR; Subkey: "PuTTYPrivateKey\shell\edit"; ValueType: string; ValueName: ""; ValueData: "&Edit"; Tasks: associate
+Root: HKCR; Subkey: "PuTTYPrivateKey\shell\edit\command"; ValueType: string; ValueName: ""; ValueData: """{app}\puttygen.exe"" ""%1"""; Tasks: associate