mirror of
https://git.tartarus.org/simon/putty.git
synced 2025-04-04 04:30:13 -05:00
7f96069954
Up-to-date trunk clang has introduced a built-in operator called _Countof, which is like the 'lenof' macro in this code (returns the number of elements in a statically-declared array object) but with the safety advantage that it provokes a compile error if you accidentally use it on a pointer. In this commit I add a cmake-time check for it, and conditional on that, switch over the definition of lenof. This should add a safety check for accidental uses of lenof(pointer). When I tested it with new clang, this whole code base compiled cleanly with the new setting, so there aren't currently any such accidents. clang cites C2y as the source for _Countof: WG14 document N3369 initially proposed it under a different name, and then there was a big internet survey about naming (in which of course I voted for lenof!), and document N3469 summarises the results, which show that the name _Countof and/or countof won. Links: https://www.open-std.org/jtc1/sc22/wg14/www/docs/n3369.pdf https://www.open-std.org/jtc1/sc22/wg14/www/docs/n3469.htm My reading of N3469 seems to say that there will _either_ be _Countof by itself, _or_ lowercase 'countof' as a new keyword, but they don't say which. They say they _don't_ intend to do the same equivocation we had with _Complex and _Bool, where you have a _Countof keyword and an optional header file defining a lowercase non-underscore macro wrapping it. But there hasn't been a new whole draft published since N3469 yet, so I don't know what will end up in it when there is. However, as of now, _Countof exists in at least one compiler, and that seems like enough reason to implement it here. If it becomes 'countof' in the real standard, then we can always change over later. (And in that case it would probably make sense to rename the macro throughout the code base to align with what will become the new standard usage.)
137 lines
4.7 KiB
CMake
137 lines
4.7 KiB
CMake
# Forcibly re-enable assertions, even if we're building in release
|
|
# mode. This is a security project - assertions may be enforcing
|
|
# security-critical constraints. A backstop #ifdef in defs.h should
|
|
# give a #error if this manoeuvre doesn't do what it needs to.
|
|
string(REPLACE "/DNDEBUG" "" CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE}")
|
|
string(REPLACE "-DNDEBUG" "" CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE}")
|
|
string(REPLACE "/DNDEBUG" "" CMAKE_C_FLAGS_RELWITHDEBINFO "${CMAKE_C_FLAGS_RELWITHDEBINFO}")
|
|
string(REPLACE "-DNDEBUG" "" CMAKE_C_FLAGS_RELWITHDEBINFO "${CMAKE_C_FLAGS_RELWITHDEBINFO}")
|
|
|
|
set(PUTTY_IPV6 ON
|
|
CACHE BOOL "Build PuTTY with IPv6 support if possible")
|
|
set(PUTTY_DEBUG OFF
|
|
CACHE BOOL "Build PuTTY with debug() statements enabled")
|
|
set(PUTTY_FUZZING OFF
|
|
CACHE BOOL "Build PuTTY binaries suitable for fuzzing, NOT FOR REAL USE")
|
|
set(PUTTY_COVERAGE OFF
|
|
CACHE BOOL "Build PuTTY binaries suitable for code coverage analysis")
|
|
set(PUTTY_COMPRESS_SCROLLBACK ON
|
|
# This is always on in production versions of PuTTY, but downstreams
|
|
# of the code have been known to find it a better tradeoff to
|
|
# disable it. So there's a #ifdef in terminal.c, and a cmake option
|
|
# to enable that ifdef just in case it needs testing or debugging.
|
|
CACHE BOOL "Store terminal scrollback in compressed form")
|
|
|
|
set(STRICT OFF
|
|
CACHE BOOL "Enable extra compiler warnings and make them errors")
|
|
|
|
include(FindGit)
|
|
|
|
set(GENERATED_SOURCES_DIR ${CMAKE_CURRENT_BINARY_DIR}${CMAKE_FILES_DIRECTORY})
|
|
|
|
set(GENERATED_LICENCE_H ${GENERATED_SOURCES_DIR}/licence.h)
|
|
set(INTERMEDIATE_LICENCE_H ${GENERATED_LICENCE_H}.tmp)
|
|
add_custom_command(OUTPUT ${INTERMEDIATE_LICENCE_H}
|
|
COMMAND ${CMAKE_COMMAND}
|
|
-DLICENCE_FILE=${CMAKE_SOURCE_DIR}/LICENCE
|
|
-DOUTPUT_FILE=${INTERMEDIATE_LICENCE_H}
|
|
-P ${CMAKE_SOURCE_DIR}/cmake/licence.cmake
|
|
DEPENDS ${CMAKE_SOURCE_DIR}/cmake/licence.cmake ${CMAKE_SOURCE_DIR}/LICENCE)
|
|
add_custom_target(generated_licence_h
|
|
BYPRODUCTS ${GENERATED_LICENCE_H}
|
|
COMMAND ${CMAKE_COMMAND} -E copy_if_different
|
|
${INTERMEDIATE_LICENCE_H} ${GENERATED_LICENCE_H}
|
|
DEPENDS ${INTERMEDIATE_LICENCE_H}
|
|
COMMENT "Updating licence.h")
|
|
|
|
set(GENERATED_COMMIT_C ${GENERATED_SOURCES_DIR}/cmake_commit.c)
|
|
set(INTERMEDIATE_COMMIT_C ${GENERATED_COMMIT_C}.tmp)
|
|
add_custom_target(check_git_commit
|
|
BYPRODUCTS ${INTERMEDIATE_COMMIT_C}
|
|
COMMAND ${CMAKE_COMMAND}
|
|
-DGIT_EXECUTABLE=${GIT_EXECUTABLE}
|
|
-DOUTPUT_FILE=${INTERMEDIATE_COMMIT_C}
|
|
-DOUTPUT_TYPE=header
|
|
-P ${CMAKE_SOURCE_DIR}/cmake/gitcommit.cmake
|
|
DEPENDS ${CMAKE_SOURCE_DIR}/cmake/gitcommit.cmake
|
|
WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
|
|
COMMENT "Checking current git commit")
|
|
add_custom_target(cmake_commit_c
|
|
BYPRODUCTS ${GENERATED_COMMIT_C}
|
|
COMMAND ${CMAKE_COMMAND} -E copy_if_different
|
|
${INTERMEDIATE_COMMIT_C} ${GENERATED_COMMIT_C}
|
|
DEPENDS check_git_commit ${INTERMEDIATE_COMMIT_C}
|
|
COMMENT "Updating cmake_commit.c")
|
|
|
|
if(CMAKE_VERSION VERSION_LESS 3.12)
|
|
function(add_compile_definitions)
|
|
foreach(i ${ARGN})
|
|
add_compile_options(-D${i})
|
|
endforeach()
|
|
endfunction()
|
|
endif()
|
|
|
|
function(add_sources_from_current_dir target)
|
|
set(sources)
|
|
foreach(i ${ARGN})
|
|
set(sources ${sources} ${CMAKE_CURRENT_SOURCE_DIR}/${i})
|
|
endforeach()
|
|
target_sources(${target} PRIVATE ${sources})
|
|
endfunction()
|
|
|
|
set(extra_dirs)
|
|
if(CMAKE_SYSTEM_NAME MATCHES "Windows" OR WINELIB)
|
|
set(platform windows)
|
|
else()
|
|
set(platform unix)
|
|
endif()
|
|
|
|
function(be_list TARGET NAME)
|
|
cmake_parse_arguments(OPT "SSH;SERIAL;OTHERBACKENDS" "" "" "${ARGN}")
|
|
add_library(${TARGET}-be-list OBJECT ${CMAKE_SOURCE_DIR}/be_list.c)
|
|
foreach(setting SSH SERIAL OTHERBACKENDS)
|
|
if(OPT_${setting})
|
|
target_compile_definitions(${TARGET}-be-list PRIVATE ${setting}=1)
|
|
else()
|
|
target_compile_definitions(${TARGET}-be-list PRIVATE ${setting}=0)
|
|
endif()
|
|
endforeach()
|
|
target_compile_definitions(${TARGET}-be-list PRIVATE APPNAME=${NAME})
|
|
target_sources(${TARGET} PRIVATE $<TARGET_OBJECTS:${TARGET}-be-list>)
|
|
endfunction()
|
|
|
|
include(cmake/platforms/${platform}.cmake)
|
|
|
|
include_directories(
|
|
${CMAKE_CURRENT_SOURCE_DIR}
|
|
${GENERATED_SOURCES_DIR}
|
|
${platform}
|
|
${extra_dirs})
|
|
|
|
check_c_source_compiles("
|
|
#define _ISOC11_SOURCE
|
|
#include <stdlib.h>
|
|
int main(int argc, char **argv) {
|
|
void *p = aligned_alloc(128, 12345);
|
|
free(p);
|
|
}" HAVE_ALIGNED_ALLOC)
|
|
|
|
check_c_source_compiles("
|
|
int main(int argc, char **argv) {
|
|
int a[3];
|
|
return _Countof(a);
|
|
}" HAVE_COUNTOF)
|
|
|
|
if(PUTTY_DEBUG)
|
|
add_compile_definitions(DEBUG)
|
|
endif()
|
|
if(PUTTY_FUZZING)
|
|
add_compile_definitions(FUZZING)
|
|
endif()
|
|
if(NOT PUTTY_COMPRESS_SCROLLBACK)
|
|
set(NO_SCROLLBACK_COMPRESSION ON)
|
|
endif()
|
|
if(PUTTY_COVERAGE)
|
|
set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fprofile-arcs -ftest-coverage -g ")
|
|
endif()
|