mirror of
https://git.tartarus.org/simon/putty.git
synced 2025-01-09 09:27:59 +00:00
c19e7215dd
This brings various concrete advantages over the previous system: - consistent support for out-of-tree builds on all platforms - more thorough support for Visual Studio IDE project files - support for Ninja-based builds, which is particularly useful on Windows where the alternative nmake has no parallel option - a really simple set of build instructions that work the same way on all the major platforms (look how much shorter README is!) - better decoupling of the project configuration from the toolchain configuration, so that my Windows cross-building doesn't need (much) special treatment in CMakeLists.txt - configure-time tests on Windows as well as Linux, so that a lot of ad-hoc #ifdefs second-guessing a particular feature's presence from the compiler version can now be replaced by tests of the feature itself Also some longer-term software-engineering advantages: - other people have actually heard of CMake, so they'll be able to produce patches to the new build setup more easily - unlike the old mkfiles.pl, CMake is not my personal problem to maintain - most importantly, mkfiles.pl was just a horrible pile of unmaintainable cruft, which even I found it painful to make changes to or to use, and desperately needed throwing in the bin. I've already thrown away all the variants of it I had in other projects of mine, and was only delaying this one so we could make the 0.75 release branch first. This change comes with a noticeable build-level restructuring. The previous Recipe worked by compiling every object file exactly once, and then making each executable by linking a precisely specified subset of the same object files. But in CMake, that's not the natural way to work - if you write the obvious command that puts the same source file into two executable targets, CMake generates a makefile that compiles it once per target. That can be an advantage, because it gives you the freedom to compile it differently in each case (e.g. with a #define telling it which program it's part of). But in a project that has many executable targets and had carefully contrived to _never_ need to build any module more than once, all it does is bloat the build time pointlessly! To avoid slowing down the build by a large factor, I've put most of the modules of the code base into a collection of static libraries organised vaguely thematically (SSH, other backends, crypto, network, ...). That means all those modules can still be compiled just once each, because once each library is built it's reused unchanged for all the executable targets. One upside of this library-based structure is that now I don't have to manually specify exactly which objects go into which programs any more - it's enough to specify which libraries are needed, and the linker will figure out the fine detail automatically. So there's less maintenance to do in CMakeLists.txt when the source code changes. But that reorganisation also adds fragility, because of the trad Unix linker semantics of walking along the library list once each, so that cyclic references between your libraries will provoke link errors. The current setup builds successfully, but I suspect it only just manages it. (In particular, I've found that MinGW is the most finicky on this score of the Windows compilers I've tried building with. So I've included a MinGW test build in the new-look Buildscr, because otherwise I think there'd be a significant risk of introducing MinGW-only build failures due to library search order, which wasn't a risk in the previous library-free build organisation.) In the longer term I hope to be able to reduce the risk of that, via gradual reorganisation (in particular, breaking up too-monolithic modules, to reduce the risk of knock-on references when you included a module for function A and it also contains function B with an unsatisfied dependency you didn't really need). Ideally I want to reach a state in which the libraries all have sensibly described purposes, a clearly documented (partial) order in which they're permitted to depend on each other, and a specification of what stubs you have to put where if you're leaving one of them out (e.g. nocrypto) and what callbacks you have to define in your non-library objects to satisfy dependencies from things low in the stack (e.g. out_of_memory()). One thing that's gone completely missing in this migration, unfortunately, is the unfinished MacOS port linked against Quartz GTK. That's because it turned out that I can't currently build it myself, on my own Mac: my previous installation of GTK had bit-rotted as a side effect of an Xcode upgrade, and I haven't yet been able to persuade jhbuild to make me a new one. So I can't even build the MacOS port with the _old_ makefiles, and hence, I have no way of checking that the new ones also work. I hope to bring that port back to life at some point, but I don't want it to block the rest of this change.
86 lines
2.7 KiB
CMake
86 lines
2.7 KiB
CMake
# Look for GTK, of any version.
|
|
|
|
set(PUTTY_GTK_VERSION "ANY"
|
|
CACHE STRING "Which major version of GTK to build with")
|
|
set_property(CACHE PUTTY_GTK_VERSION
|
|
PROPERTY STRINGS ANY 3 2 1)
|
|
|
|
set(GTK_FOUND FALSE)
|
|
|
|
macro(try_pkg_config_gtk VER PACKAGENAME)
|
|
if(NOT GTK_FOUND AND
|
|
(PUTTY_GTK_VERSION STREQUAL ANY OR PUTTY_GTK_VERSION STREQUAL ${VER}))
|
|
find_package(PkgConfig)
|
|
pkg_check_modules(GTK ${PACKAGENAME})
|
|
endif()
|
|
endmacro()
|
|
try_pkg_config_gtk(3 gtk+-3.0)
|
|
try_pkg_config_gtk(2 gtk+-2.0)
|
|
|
|
if(NOT GTK_FOUND AND
|
|
(PUTTY_GTK_VERSION STREQUAL ANY OR PUTTY_GTK_VERSION STREQUAL 1))
|
|
message("-- Checking for GTK1 (via gtk-config)")
|
|
find_program(GTK_CONFIG gtk-config)
|
|
if(GTK_CONFIG)
|
|
execute_process(COMMAND ${GTK_CONFIG} --cflags
|
|
OUTPUT_VARIABLE gtk_config_cflags
|
|
OUTPUT_STRIP_TRAILING_WHITESPACE
|
|
RESULT_VARIABLE gtk_config_cflags_result)
|
|
execute_process(COMMAND ${GTK_CONFIG} --libs
|
|
OUTPUT_VARIABLE gtk_config_libs
|
|
OUTPUT_STRIP_TRAILING_WHITESPACE
|
|
RESULT_VARIABLE gtk_config_libs_result)
|
|
|
|
if(gtk_config_cflags_result EQUAL 0 AND gtk_config_libs_result EQUAL 0)
|
|
|
|
set(GTK_INCLUDE_DIRS)
|
|
set(GTK_LIBRARY_DIRS)
|
|
set(GTK_LIBRARIES)
|
|
|
|
separate_arguments(gtk_config_cflags NATIVE_COMMAND
|
|
${gtk_config_cflags})
|
|
foreach(opt ${gtk_config_cflags})
|
|
string(REGEX MATCH "^-I" ok ${opt})
|
|
if(ok)
|
|
string(REGEX REPLACE "^-I" "" optval ${opt})
|
|
list(APPEND GTK_INCLUDE_DIRS ${optval})
|
|
endif()
|
|
endforeach()
|
|
|
|
separate_arguments(gtk_config_libs NATIVE_COMMAND
|
|
${gtk_config_libs})
|
|
foreach(opt ${gtk_config_libs})
|
|
string(REGEX MATCH "^-l" ok ${opt})
|
|
if(ok)
|
|
list(APPEND GTK_LIBRARIES ${opt})
|
|
endif()
|
|
string(REGEX MATCH "^-L" ok ${opt})
|
|
if(ok)
|
|
string(REGEX REPLACE "^-L" "" optval ${opt})
|
|
list(APPEND GTK_LIBRARY_DIRS ${optval})
|
|
endif()
|
|
endforeach()
|
|
|
|
message("-- Found GTK1")
|
|
set(GTK_FOUND TRUE)
|
|
endif()
|
|
endif()
|
|
endif()
|
|
|
|
if(GTK_FOUND)
|
|
# Check for some particular Pango functions.
|
|
function(pango_check_subscope)
|
|
set(CMAKE_REQUIRED_INCLUDES ${GTK_INCLUDE_DIRS})
|
|
set(CMAKE_REQUIRED_LIBRARIES ${GTK_LIBRARIES})
|
|
check_symbol_exists(pango_font_family_is_monospace "pango/pango.h"
|
|
HAVE_PANGO_FONT_FAMILY_IS_MONOSPACE)
|
|
check_symbol_exists(pango_font_map_list_families "pango/pango.h"
|
|
HAVE_PANGO_FONT_MAP_LIST_FAMILIES)
|
|
set(HAVE_PANGO_FONT_FAMILY_IS_MONOSPACE
|
|
${HAVE_PANGO_FONT_FAMILY_IS_MONOSPACE} PARENT_SCOPE)
|
|
set(HAVE_PANGO_FONT_MAP_LIST_FAMILIES
|
|
${HAVE_PANGO_FONT_MAP_LIST_FAMILIES} PARENT_SCOPE)
|
|
endfunction()
|
|
pango_check_subscope()
|
|
endif()
|