#!groovy

def repository = "registry.c.test-chamber-13.lan"
def repositoryCreds = "harbor-repository-creds"

def label = "kubernetes-${UUID.randomUUID().toString()}"
def templateName = "pipeline-worker"


def dockerFile = """
FROM ${repository}/library/alpine:latest as certHost

FROM ${repository}/dockerhub/library/golang:alpine as builder

COPY . /go/src/app

WORKDIR /go/src/app

RUN apk add --no-cache git upx && \\
    addgroup -S -g 1000 app && \\
    adduser --disabled-password -G app --gecos "application account" --home "/home/app" --shell "/sbin/nologin" --no-create-home --uid 1000 app && \\
    go get -d -v ./... && \\
    go install -v ./... && \\
    GOOG=linux GOARCH=amd64 CGO_ENABLED=0 go build -v -ldflags="-s -w" -tags timetzdata -o app ./cmd/tpapi && \\
    upx --lzma app

FROM scratch

COPY --from=certHost /etc/ssl/certs/ca-certificates.crt /etc/ssl/certs/
COPY --from=builder /etc/passwd /etc/group /etc/
COPY --from=builder --chown=app:app /go/src/app/app /app/app

USER app:app
WORKDIR /app/

ENTRYPOINT ["/app/app"]
"""


podTemplate(
    label: label,
    name: templateName,
    yaml: functions.podYaml(
        repo: repository,
        templateName: templateName,
        kaniko: true,
        alpine: true,
        [
            [
                name: "sonar",
                path: "${repository}/library/sonarscanner:latest",
                command: "/bin/sh"
            ],
            [
                name: "golang",
                path: "${repository}/dockerhub/library/golang:alpine",
                command: "/bin/sh"
            ]
        ]
    )
) {
    node (label) {
        def workspace = pwd()

        stage('Clone Repository') {
            checkout ([$class: "GitSCM",
                branches: scm.branches,
                extensions: scm.extensions + [$class: 'CloneOption', shallow: true],
                userRemoteConfigs: scm.userRemoteConfigs,
            ])
            shortCommit = sh(returnStdout: true, script: "git log -n 1 --pretty=format:'%h'").trim()
        }

        stage('Run Tests') {
            container('golang') {
                writeFile(file: workspace + "/test-chamber-13.lan.root.crt", text: functions.getLocalRootCA())
                sh """
                    apk add --no-cache curl gcc musl-dev
                    curl \
                      --silent \
                      --location \
                      --cacert "${workspace}/test-chamber-13.lan.root.crt" \
                      https://nexus.c.test-chamber-13.lan/repository/github-releases/jstemmer/go-junit-report/releases/download/v1.0.0/go-junit-report-v1.0.0-linux-amd64.tar.gz \
                    | tar -z -x -f - -C /usr/local/bin
                    ln -s "${workspace}" "/go/src/${env.JOB_BASE_NAME}"
                    cd "/go/src/${env.JOB_BASE_NAME}"
                    go get -d -v ./...
                    go install -v ./...
                    go test -short -coverprofile=cover.out ./...
                    go test -v ./... 2>&1 | go-junit-report > report.xml
                """
            }
        }

       stage('Prepare SonarScanner') {
            def sonarScannerConfig = """
sonar.projectKey=emonesp-exporter
sonar.projectVersion=${shortCommit}
sonar.sources=.
sonar.exclusions=**/*_test.go,**/vendor/**,**/testdata/*
sonar.tests=.
sonar.test.inclusions=**/*_test.go
sonar.test.exclusions=**/vendor/**
sonar.go.coverage.reportPaths=cover.out
"""
            writeFile file: 'sonar-project.properties', text: sonarScannerConfig
        }

        stage('SonarQube Analysis') {
            container('sonar') {
                withSonarQubeEnv('SonarQube') {
                    sh "sonar-scanner --define sonar.host.url=https://sonar.c.test-chamber-13.lan"
                }
            }
        }

        stage("Build tplinkcmd") {
            container("golang") {
                sh """
                    apk add --no-cache upx
                    go install -v ./...
                    GOOS=linux GOARCH=amd64 CGO_ENABLED=0 go build -v -ldflags="-s -w" -tags timetzdata -o tplink ./cmd/tpstate
                    upx --lzma tplink
                """
            }
        }

        stage ("Store Artifacts") {
            archiveArtifacts (artifacts: "tplink",
                fingerprint: true,
                allowEmptyArchive: false,
                onlyIfSuccessful: true,
            )
        }

        stage ('Push Artifacts') {
            container('alpine') {
                functions.pushArtifact(
                    repoCreds: "nexus-generic-upload-bot",
                    fileName: "tplink",
                    filePath: workspace + "/",
                    fileURL: "https://nexus.c.test-chamber-13.lan/repository/generic/go/"
                )
            }
        }

        functions.buildContainer(
            repository: repository,
            imageDest: "${repository}/library/tplink-api:latest",
            dockerFile: dockerFile,
            repoCreds: repositoryCreds
        )

        stage('Delete Running Pod') {
            functions.deletePod(
                kubeAuth: "k8s-webservers-access",
                kubeURL: "https://kubernetes.test-chamber-13.lan:6443",
                namespace: "webservers",
                selector: "app=tplink-api"
            )
        }

        stage('Submit Testing Report to Jenkins') {
            catchError{
                junit 'report.xml'
            }
        }

    }
}